"[GDS|Entropy]" <gds### [at] hotmailcom> wrote in message 
news:498a1e72@news.povray.org...
>
> Here are some skies I made way back in 1999-2000, they aren't anything 
> fancy like the media skies I've seen people make...but I like them. So 
> here they are, in all of their unhallowed darkness.

From the good ol' days... ;)

> BTW S_S3 is a darker version of S_S1, and S_S2 has some options in the 
> .inc file. I might actually improve/finish these if people actually like 
> them.
>
> You will find the source in p.b.s-f.

> As a side note...is it possible to turn these into media skies?

Not sure putting orthographic images of each textured plane into DF3 would 
have the same appearance but that's all I can think of.

Media may be slow but I sure like it for clouds. I just now tried putting a 
simple cloudy sky together and got this somewhat stormy scene (small image 
attached rendered 2m 30s on AMD dual core 2.0 GHz so isn't fast of course):

/* BEGIN */
#declare CloudsLow=
density{bozo turbulence 0.5
        density_map{[0 rgb <0.7,0.9,1>][0.5 rgb <0.8,0.9,1>][0.55 rgb 0]}}

#declare CloudsHigh=
density{bozo turbulence 0.5
        density_map{[0 rgb 1][0.5 rgb <0.99,0.99,0.9>*2][0.525 rgb 0]}}

intersection
{
        plane{-y,0}
        plane{y,1}
//        plane{-z,-5}
        pigment{rgbt 1}
        interior{
                media{
                        samples 20 // could need more
                        absorption <0.5,0.45,0.4>/2
                        scattering{1,<0.4,0.45,0.5>*2}
                        density{
                                gradient y
                                density_map{
                                        [0 rgb 0]
                                        [0.1 CloudsLow]
                                        [0.5 CloudsHigh]
                                        [1 rgb 0]
                                }
                                ramp_wave
                        }
                }
        }
        rotate 5*x
        translate 3*y
        hollow on
}

light_source{<100,100,-100>,1}

camera{location -z/2 look_at y/8}

sky_sphere{
        pigment{gradient y
        color_map{[0 rgb <0.8,0.7,0.6>][1 rgb <0.2,0.5,0.8>]}
        rotate 5*x
}}

fog{fog_type 2 color <0.5,0.45,0.4> distance 5 fog_alt 0.1 fog_offset -0.1}

plane{y,-0.1 pigment {bozo}}
/* END */

Post a reply to this message

Attachments:
Download 'media clouds test.jpg' (18 KB)

Preview of image 'media clouds test.jpg'